『分享』在rpgle中使用EXTNAME和LIKEREC定義DS

pantierui

我們可以在rpgle中使用LIKEREC來定義DS、DS的子字段、procedures的返回值或procedure的參數(shù)。

關(guān)鍵字LIKEREC的定義格式如下：
LIKEREC(intrecname{:*ALL|*INPUT|*OUTPUT |*KEY})
LIKEREC參數(shù)1：intrecname就是定義DS等時引用的內(nèi)部文件的record名
EXTNAME參數(shù)3：*ALL|*INPUT|*OUTPUT|*KEY的意思是提取format中符號參數(shù)的字段來定義DS等。
*ALL:提取全部字段
*INPUT：只提取輸入字段
*OUTPUT：只提取輸出字段
*KEY：只提取key字段

關(guān)鍵字EXTNAME & EXTFLD的定義格式如下：
EXTNAME(file-name{:format-name}{:*ALL| *INPUT|*OUTPUT|*KEY})
EXTFLD(field_name)

EXTNAME參數(shù)1：file-name就是定義DS時引用的外部文件
EXTNAME參數(shù)2：format-name就是引用的外部文件的format，如果又多個format的時候。
EXTNAME參數(shù)3：與LIKEREC意義相同

EXTFLD是重命名EXTNAME引用的字段的。

EXTNAME只能用來定義DS，不能定義DS的子字段。
d dcustom       e ds                  extname(custom:*key)  QUALIFIED
上面是可以的，但下面就不被允許了。
d dcustom         ds                 
d  subfld                             extname(custom:*key)  QUALIFIED

下面是具體的例子：
DB FILE: CUSTOM
                R CUSTOMR                   TEXT('CUSTOMER FILE')
                  CUST           5          TEXT('CUSTOMER NUMBER')
                                            COLHDG('CUSTOMER NUMBER')
                  NAME          20          TEXT('CUSTOMER NAME')
                                            COLHDG('CUSTOMER NAME')
                  ADDR          20          TEXT('CUSTOMER ADDRESS')
                                            COLHDG('CUSTOMER ADDRESS')
                  CITY          20          TEXT('CUSTOMER CITY')
                                            COLHDG('CUSTOMER CITY')
                  STATE          2          TEXT('STATE ABBREVIATION')
                                            COLHDG('STATE ABBREVIATION')
                  ZIP            5  0       TEXT('ZIP CODE')
                                            COLHDG('ZIP CODE')
                  ARBAL         10  2       TEXT('ACCOUNTS RECEIVABLE BALANCE')
                                            COLHDG('ACCOUNTS RECEIVABLE '-
                                             'BALANCE')
                K CUST
                K STATE

DSP FILE:TESTDSP
     A                                      DSPSIZ(24 80 *DS3)
     A                                      CA03
     A          R DSP1R
     A            FLDA           5A  I  1 25
     A            FLDB           2A  I  2 25
     A            FLDC           2Y 0B  3 25
     A            FLDD           2Y 0O  4 25
     A          R DSP2R
     A            FLDE           5A  O  5 25
     A            FLDF           2A  O  6 25
     A            FLDG           2Y 0B  7 25
     A            FLDH           2Y 0I  8 25

LIKEREC程序例子
RPGLE FILE:TEST1
     hDFTACTGRP(*NO)
     fcustom    if   e           k disk
     ftestdsp   cf   e             WORKSTN
     d************************ Data Structure **********************************
     d dsCustom        ds                  likerec(customr:*key)
     d dsDSPi          ds                  likerec(DSP1R:*input)
     d dsDSPo          ds                  likerec(DSP2R:*output)
     d*
     d wait            s              1a
     d func            pr                  likerec(customr:*key)
     d  parmA                              likerec(dsp1r:*input)
     c*
      /free
             // manipulate *key field
                         dscustom.cust = 'key';
                         dsply     dscustom.cust  wait;
             // manipulate *input field
                         dsDSPi.flda = 'input';
                         dsply     dsDSPi.flda     wait;
             // manipulate *output field
                         dsDSPo.flde = 'outpt';
                         dsply     dsDSPo.flde     wait;
             // manipulate procedure return value & procedure parameter
                         eval      dsCustom = func(dsDSPi);
                         dsply     dsCustom.state  wait;
      /end-free
     c*
     c                   SETON                                        LR
     c                   RETURN
     p func            b
     d*
     d func            pi                  likerec(customr:*key)
     d  parmA                              likerec(dsp1r:*input)
     d*
     d fdscustom       ds                  likerec(customr:*key)
     d*
     c                   eval      fdscustom.cust = parmA.flda
     c                   eval      fdscustom.STATE = %subst(parmA.flda:1:2)
     c                   return    fdscustom
     p func            e

EXTNAME程序例子：
RPGLE FILE:TEST
     d dcustom       e ds                  extname(custom:*key)  QUALIFIED
     d  custID       e                     extfld(CUST)
     d dsDSPi        e ds                  extname(TESTDSPSP1R:*input)
     d                                     QUALIFIED
     d dsDSPo        e ds                  extname(TESTDSPSP2R:*output)
     d                                     QUALIFIED
     d wait            s              1a
     c*
      /free
             // manipulate *key field
                         dcustom.custID = '*key';
                         dsply     dcustom.custID  wait;
             // manipulate *input field
                         dsDSPi.flda = '*input';
                         dsply     dsDSPi.flda     wait;
             // manipulate *output field
                         dsDSPo.flde = '*output';
                         dsply     dsDSPo.flde     wait;
      /end-free
     c*
     c                   SETON                                        LR
     c                   RETURN

LIKEREC和EXTNAME都可以用來定義DS，那他們的區(qū)別是什么那，我認(rèn)為有以下幾點：
1.EXTNAME只能定義DS，不能用來定義DS的子字段、procedure的返回值和procedure的參數(shù)。而LIKEREC可以。
2.從引用的文件角度講，EXTNAME引用的文件不需要在F表中聲明，而LIKEREC必須在F表中聲明。
3.從使用的角度來講，如果EXTNAME定義的DS想要DS.SUBFIELD這樣使用，必須在定義時使用關(guān)鍵字QUALIFIED，而LIKEREC則不用，因為LIKEREC定義的DS自動添加了關(guān)鍵字QUALIFIED。

歡迎大家來拍磚~~~


【update】
在使用上extname和likerec有些不同，如下面的例子
第一種方式（采用關(guān)鍵字LIKEREC）：
F KKPCEP00  IF   E           K DISK                                                                          
D*                                                      
D W#DS             DS                  LIKEREC(KKPCER)   
D PCEDS            DS                  QUALIFIED
D W#FLG                           1A            
D PCE01                           2A            
D PCE02                           2A      
...
C     W#FLG#        CHAIN     KKPCEP00      W#DS   
C                   EVAL      PCEDS =W#DS               


第二種方式（采用關(guān)鍵字EXTNAME）：
F KKPCEP00  IF   E           K DISK                                                                          
D*  
D W#DS           E DS                  EXTNAME(KKPCEP00)
D PCEDS            DS                  QUALIFIED   
D W#FLG                           1A            
D PCE01                           2A            
D PCE02                           2A  
  ...
C     W#FLG#        CHAIN     KKPCEP00        
C                   EVAL      PCEDS =W#DS

在第二種方式在執(zhí)行完chain后W#DS就會有chain到的值。而如果要想用likerec定義ds也有值，那就的是如下的寫法
C     W#FLG#        CHAIN     KKPCEP00      W#DS   

主要的原因是QUALIFIED，因為likerec定義的ds會自動添加QUALIFIED，我在上面有說。

持續(xù)更新中。。。。。

qingzhou

支持分享~~~ 謝謝！

愛笑的貓貓

支持，叁Q

xjromance

討論完畢前來拍磚

eleven7799

qihboy

PTR V5

尹少俠

回復(fù) 1# pantierui