文本行橫豎轉換

waker

改的好讀一點兒吧

1. 
   
2. H            #保存所有行
   
3. ${          #最后一行處理，與AWK的END相似
   
4. :a
   
5. g            #取得保留空間內容
   
6. s/\n[^\n]/\n/g       #把第一個不是換行符刪除
   
7. :b                                      #與下面一句形成循環(huán)
   
8. /[^\n]/s/\n\n/\n \n/g;tb    #其實是補位用的
   
9. x                                       #交換保留/模式空間內容，這時保留空間已經沒有每"行"的第一個字符了
   
10. s/\n\+\([^\n]\)[^\n]*/\1/gp;ta   #打印出模式空間的所有"行"的第一個字符，再去:a處處理保留空間的內容
    
11. }
    

復制代碼

faintblue

原帖由 waker 于 2006-1-12 09:12 發(fā)表
... 當然部分不支持\n的用戶不能通過 ...

Yes, many sed versions don't support \n as a replacement.

r2007

空行沒有考慮吧？
1234567

drmfslx

r2007

原帖由 faintblue 于 2006-1-12 11:12 發(fā)表


Yes, many sed versions don't support \n as a replacement.

這樣是否移植性更好？

1. sed -n 'H;${:a;
   
2. g;
   
3. s/\(\n\)[^\n]/\1/g;
   
4. :b;
   
5. /[^\n]/s/\(\n\)\1/\1 \1/g;tb;
   
6. x;
   
7. s/\n\+\([^\n]\)[^\n]*/\1/gp;ta}'
   

復制代碼

r2007

加了一行就出問題了

1. cat file
   
2. 123456
   
3. abc
   
4. ABCDE
   
5. hijk
   
6. lmnopqrstuvw
   
7. ^_^

復制代碼

結果

1. 1aAhl^
   
2. 2bBim_
   
3. 3cCjn^
   
4. 4 Dko
   
5. 
   
6. 5 E p
   
7. 
   
8. 6   q
   
9. 
   
10.     r
    
11. 
    
12.     s
    
13. 
    
14.     t
    
15. 
    
16.     u
    
17. 
    
18.     v
    
19. 
    
20.     w
    

復制代碼

waker

空行好解決
最前面加
/^$/s// /

多換行的問題還得考慮

faintblue

原帖由 r2007 于 2006-1-12 12:02 發(fā)表

這樣是否移植性更好？

s/\n\+\([^\n]\)[^\n]*/\1/gp;ta}'

+ is bad for 移植性.

waker

再修訂一次吧，雖然不能滿足所有sed版本
不過感覺還有修改空間

1. sed -n '/^$/s// /
   
2. H
   
3. ${
   
4. :a
   
5. g
   
6. s/\(\n\)[^\n]/\1/g
   
7. :b
   
8. /[^\n]/s/\(\n\)\1/\1 \1/g
   
9. tb
   
10. x;
    
11. s/\n\n*\([^\n]\)[^\n]*/\1/g
    
12. s/\n//g
    
13. /[^\n]/{p;ba}
    
14. }' file
    

復制代碼

dbcat

感謝螞蟻,烈火,FAINTBLUE , WAKER ,R2007 的無私幫助!
問題圓滿解決!
向你們致敬!

[ 本帖最后由 dbcat 于 2006-1-12 17:13 編輯 ]

大螞蟻

呵呵，我是來學習的，建議美女把帖子改個名字，以后方便查閱